home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Wildcat Files 2
/
The Wildcat Files 2 (Arsenal Computer).ISO
/
qm-util
/
automail.scr
< prev
next >
Wrap
Text File
|
1994-04-02
|
4KB
|
130 lines
;This is a script to make unattended mail runs from a BBS thru a batch file
;using Q-Modem Pro. You will need to "customize" this script to suit your
;needs. I would not recommend setting the redial limit more than 10 attempts
;otherwise, you will get an error "TOO MANY WHEN'S". If you have any
;suggestions for improvements, please let me know.
;Eddie Dukes
;The Tiger's Den
;Columbia, SC
;(803) 798-5068
TURNON 8_BIT
TURNOFF LINEFEED
TURNOFF NOISE
TURNOFF MUSIC
TURNON SCROLL
TURNOFF PRINT
TURNOFF ECHO
TURNOFF SPLIT
TURNON STATUSLN
TURNOFF DOORWAY
STRING QWKFILE REPFILE QWKPATH REPPATH TELNUM LIMIT
STRING INITIAL DOOR XFER NAME HOSTNAME
ASSIGN HOSTNAME "THE BBS TO CALL" ;The BBS you want to call
ASSIGN QWKFILE MAIL.QWK ;The name of .QWK packet
ASSIGN REPFILE MAIL.REP ;The name of the .REP packet
ASSIGN QWKPATH C:\DNLOAD\ ;Your .QWK download directory
ASSIGN REPPATH C:\UPLOAD\ ;Your .REP upload directory
ASSIGN DOOR D ;Maybe "T" for TomCat
ASSIGN XFER Z ;Your download protocol
ASSIGN NAME "!NODE NAME 1234" ;Your Node name and password
ASSIGN TELNUM "ATDT 5551234^M" ;The BBS phone # you're calling
ASSIGN LIMIT 5 ;# of times you want to re-dial
ASSIGN INITIAL "AT&F2E0M^M" ;Your modem init. string
SETCOMM 19200 8 NONE 1
;---------------------------- Initialize the Modem ----------------------
INIT:
SEND "ATHM^M"
DELAY 1000
ASSIGN 0 $LIMIT
CLRSCR
DISPLAY "Initializing Modem ... "
DELAY 1000
SEND "$INITIAL"
WAITFOR "OK"
;----------------------------- Dial the Board ---------------------------
GETON:
WHEN "BUSY" AGAIN
WHEN "NO CARRIER" AGAIN
PAUSE 2000
DECR 0
IF "$0" < "1" GETOUT
TIMEOUT 60 GETON
CLRSCR
DISPLAYLN "Attempting to connect with $HOSTNAME"
DISPLAYLN "Dial attempts left are $0"
DISPLAYLN "Dialing string: $TELNUM"
DELAY 100
SEND "$TELNUM"
WAITFOR "CONNECT"
GOTO ONTHESYSTEM
AGAIN:
PAUSE 1000
SEND "ATH1M^M"
PAUSE 5000
GOTO GETON
;-------------------- We have connected to the System ------------------
ONTHESYSTEM:
WAITFOR "first name"
DELAY 100
SEND "$NAME^M"
WHEN "NO CARRIER" GETOUT
TIMEOUT 600 GETOUT
SEND "^M"
;-------------------- Call for the Download of the Mail Packet ---------
DOWNSECTION:
DL:
SEND "^M"
WAITFOR "TOMCAT MENU"
DELAY 100
SEND "D^M"
WHEN "to download!" UPSECTION
WHEN "NO CARRIER" GETOUT
WAITFOR "oodbye when done"
DELAY 1000
SEND "Y^M"
WHEN "Insufficient time" UPSECTION
WAITFOR "Start"
DELAY 100
DOWNLOAD $XFER $QWKPATH$QWKFILE
DELAY 200
;-------------------------- Lets Upload the Replies ---------------------
UPSECTION:
SEND "^M"
WHEN "NO CARRIER" GETOUT
SEND "^M"
WAITFOR "TOMCAT MENU"
DELAY 100
EXIST $REPPATH$REPFILE SENDEM
GOTO GETOUT
SENDEM:
SEND "U^M"
DELAY 100
WAITFOR "Start"
PAUSE 1000
UPLOAD $XFER $REPPATH$REPFILE
WHEN "Transfer UNCESSFUL!" UPSECTION
DOS "DEL $REPPATH$REPFILE
GOTO ALLDONE
;--------------------------- Lets get out of Here ----------------------
ALLDONE:
SEND "^M"
WAITFOR "TOMCAT MENU"
DELAY 100
SEND "G^M"
PAUSE 5000
GETOUT:
HANGUP
SEND "ATZ^M^~^~^~^~^~^~ATH1M0^M"
SYSTEM Y
EXIT